LUA_ERRERR: ошибка при управлении _ERRORMESSAGE

Я не знаю PowerBasiс'а, но с точки зрения API такой код должен работать корректно

z00n wrote:Я не знаю PowerBasiс'а, но с точки зрения API такой код должен работать корректно

Обработки ошибок в оригинальном коде действительно не хватало.
Но корректно работать не будет, так как:
1. Ф-ции lua_loadfile не существует - есть luaL_loadfile
2. start - это не имя файла, а имя глобальной функции.

smz wrote:
Но корректно работать не будет, так как:
1. Ф-ции lua_loadfile не существует - есть ...

Спасибо, это я спросонья

Вот, написал на PB упрощенный вариант - работает совершенно корректно, откопилированный вариант для экспериментов прилагается.

' //file: tojangle.bas
#COMPILE EXE
#DIM ALL

' //--- LUA 5.1 API
' //Option for multiple returns in lua_call
%LUA_MULTRET = -1

' //Pseudo-indices
%LUA_REGISTRYINDEX   = (-10000)
%LUA_ENVIRONINDEX    = (-10001)
%LUA_GLOBALSINDEX    = (-10002)

' //Types returned by lua_type
%LUA_TNONE          = -1
%LUA_TNIL           = 0
%LUA_TBOOLEAN       = 1
%LUA_TLIGHTUSERDATA = 2
%LUA_TNUMBER        = 3
%LUA_TSTRING        = 4
%LUA_TTABLE         = 5
%LUA_TFUNCTION      = 6
%LUA_TUSERDATA      = 7
%LUA_TTHREAD        = 8

' //Imports
DECLARE FUNCTION LuaL_NewState LIB "lua51.dll" ALIAS "luaL_newstate" _
    () AS DWORD
DECLARE SUB      Lua_Close     LIB "lua51.dll" ALIAS "lua_close" _
    (BYVAL l AS DWORD)
DECLARE SUB      LuaL_OpenLibs LIB "lua51.dll" ALIAS "luaL_openlibs" _
    (BYVAL l AS DWORD)
DECLARE FUNCTION LuaL_LoadFile LIB "lua51.dll" ALIAS "luaL_loadfile" _
    (BYVAL l AS DWORD, BYVAL n AS STRING) AS LONG
DECLARE FUNCTION Lua_Pcall     LIB "lua51.dll" ALIAS "lua_pcall" _
    (BYVAL l AS DWORD, BYVAL args AS LONG, BYVAL results AS LONG, _
     BYVAL errfun AS LONG) AS LONG
DECLARE FUNCTION Lua_ToLString LIB "lua51.dll" ALIAS "lua_tolstring" _
    (BYVAL l AS DWORD, BYVAL i AS LONG, ll AS DWORD) AS STRING
DECLARE SUB Lua_PushNumber     LIB "lua51.dll" ALIAS "lua_pushnumber"  _
    (BYVAL l AS DWORD, BYVAL n AS DOUBLE)
DECLARE SUB Lua_PushString     LIB "lua51.dll" ALIAS "lua_pushstring"  _
    (BYVAL l AS DWORD, BYVAL sp AS STRING)

FUNCTION Lua_ToString(BYVAL hLua AS DWORD, BYVAL istack AS LONG) AS STRING
    FUNCTION = Lua_ToLString(hLua,istack,0)
END FUNCTION

' //+++ MAIN +++
FUNCTION PBMAIN ()
    LOCAL hLua   AS DWORD
    LOCAL result AS LONG

' //sturtup Lua
    hLua = luaL_newstate()

luaL_openlibs(hLua)

' //load script.lua
    result = luaL_loadfile(hLua,"script.lua")

IF result <> 0 THEN
        MSGBOX(lua_tostring(hLua,-1))
        GOTO ExitLBL
    END IF

' //pass args to script.lua
    lua_pushnumber(hLua,42)                ' //ARG#1
    lua_pushstring(hLua,"somestring")      ' //ARG#2

' //call script.lua
    result = lua_pcall(hlua,2,1,0)         ' //2 args, 1 result
    IF result <> 0 THEN
        MSGBOX(lua_tostring(hlua,-1))
        GOTO ExitLBL
    END IF

' //get some return from script.lua
    MSGBOX "script.lua returns: " & lua_tostring(hLua,-1)

ExitLBL:
    lua_close(hLua)
END FUNCTION

z00n - cпасибо за код! Оказывается в хидерах которые я использовал, декларации Lua - функций были другими, видимо здесь источник всех проблем.
Теперь все заработало правильно!